bundle agent main
{
  vars:
      'pkg'     string => 'bash';
      'oldver'  string => '5.0.17';
      'repo'    string => 'CFE-3568';

  methods:
    !cleanup::
      '' usebundle => install_architecture($(pkg));
      '' usebundle => update($(pkg), $(oldver));

      '' usebundle => create_repository($(repo));
      '' usebundle => install_repository($(repo), $(pkg));

    cleanup::
      '' usebundle => remove_repository($(repo));
      '' usebundle => install($(pkg));
}

bundle agent install(pkg)
{
  packages:
      '$(pkg)'
          policy => 'absent';
      '$(pkg)'
          policy  => 'present',
          classes => lresults;

  reports:
      '* bundle   : $(this.bundle)';
      '  results  : $(with)'
          with => join(' ', classesmatching('_.*'));
      '  installed: $(with)'
          with => join(' ', mapdata('none', '$(this.v)', packagesmatching('$(pkg)', '.*', '.*', '.*')));
}

bundle agent install_architecture(pkg)
{
  vars:
      'arch' string => execresult('/usr/bin/uname -m', noshell);

  packages:
      '$(pkg)'
          policy => 'absent';
      '$(pkg)'
          policy        => 'present',
          architecture  => $(arch),
          classes       => lresults;

  reports:
      '* bundle   : $(this.bundle)';
      '  results  : $(with)'
          with => join(' ', classesmatching('_.*'));
      '  installed: $(with)'
          with => join(' ', mapdata('none', '$(this.v)', packagesmatching('$(pkg)', '.*', '.*', '.*')));
}

bundle agent update(pkg, oldver)
{
  packages:
      '$(pkg)'
          handle => '$(this.namespace)_$(this.bundle)_step_1',
          policy => 'absent';
      '/var/cache/pkg/$(pkg)-$(oldver).txz'
          policy      => 'present';
      '$(pkg)'
          policy      => 'present',
          version     => 'latest',
          classes     => lresults;

  reports:
      '* bundle   : $(this.bundle)';
      '  results  : $(with)'
          with => join(' ', classesmatching('_.*'));
      '  installed: $(with)'
          with => join(' ', mapdata('none', '$(this.v)', packagesmatching('$(pkg)', '.*', '.*', '.*')));
}

bundle agent install_repository(repo, pkg)
{
  packages:
      '$(pkg)'
          policy => 'absent';
      '$(pkg)'
          comment => 'This promise should fail as the package is not present in the referred repo.',
          policy  => 'present',
          options => { 'repository=$(repo)' },
          classes => lresults;

  reports:
      '* bundle   : $(this.bundle)';
      '  results  : $(with)'
          with => join(' ', classesmatching('_.*'));
      '  installed: $(with)'
          with => join(' ', mapdata('none', '$(this.v)', packagesmatching('$(pkg)', '.*', '.*', '.*')));
}

bundle agent create_repository(repo)
{
  vars:
      'path'      string => '/tmp/$(repo)-repo';
      'repoconf'  string => '
$(repo): {
  url: "file://$(path)",
  enabled: true,
  mirror_type: "none"
}
';

  files:
      '/usr/local/etc/pkg/repos/.'
          create  => 'true';
      '/usr/local/etc/pkg/repos/$(repo).conf'
          create                => 'true',
          template_method       => 'inline_mustache',
          edit_template_string  => '$(repoconf)';
      '$(path)/.'
          create  => 'true';
      '$(path)/fake.txz'
          create  => 'true';

  commands:
      '/usr/sbin/pkg repo -q $(path)'
          contain => silent;
      '/usr/sbin/pkg update -fqr $(repo)';
}

bundle agent remove_repository(repo)
{
  vars:
      'path' string => '/tmp/$(repo)-repo';

  files:
      '/usr/local/etc/pkg/repos/$(repo).conf'
          delete => rm;

  commands:
      '/bin/rm -rf $(path)';
      '/usr/sbin/pkg update -q';
}

body contain silent
{
  no_output => 'true';
}

body delete rm
{
  dirlinks  => 'delete';
  rmdirs    => 'false' ;
}

body classes lresults
{
  scope => 'bundle';
  promise_kept      => { '_reached', '_ok', '_kept' };
  promise_repaired  => { '_reached', '_ok', '_repaired' };
  repair_failed     => { '_reached', '_error', '_not_kept', '_failed' };
  repair_denied     => { '_reached', '_error', '_not_kept', '_denied' };
  repair_timeout    => { '_reached', '_error', '_not_kept', '_timeout' };
}

body package_module pkg
{
  query_installed_ifelapsed => "0";
  query_updates_ifelapsed   => "0";
}

body common control
{
  package_module    => 'pkg';
  package_inventory => {'pkg'};
}